BBS in a Box 3/BBS in a box - Trilogy III.iso/Files/Prog/N-P/OmniScript 2.0.1/Examples/Finder Examples/Finder Play

Text File | 1993-09-10 | 3.5 KB | 184 lines | [TEXT/ExPr]

$list = 0
$dest = 0
a = '"Initialize List" "Add Files" "Add A Folder" "Select Destination" "Destination Trash" "Destination Desktop"'
lval a,xList
menu new,20,0,xList
xFunction[1] = "Show About"
$b[1] = "showabout"
xFunction[2] = "Hide About"
$b[2] = "hideabout"
xFunction[3] = "Show Clip"
$b[3] = "showclip"
xFunction[4] = "Hide Clip"
$b[4] = "hideclip"
xFunction[5] = "Empty Trash"
$b[5] = "empty"
xFunction[6] = "-("
xFunction[7] = "Open"
$b[7] = "open"
xFunction[8] = "Print"
$b[8] = "print"
xFunction[9] = "Get Info"
$b[9] = "info"
xFunction[10] = "Sharing"
$b[10] = "sharing"
xFunction[11] = "Duplicate"
$b[11] = "duplicate"
xFunction[12] = "Make Alias"
$b[12] = "alias"
xFunction[13] = "Put Away"
$b[13] = "putaway"
xFunction[14] = "-("
xFunction[15] = "Move"
$b[15] = "move"
xFunction[16] = "Drag"
$b[16] = "drag"
xFunction[17] = "-("
xFunction[18] = "Show"
$b[18] = "show"
xFunction[19] = "Close"
$b[19] = "close"
xFunction[20] = "Close Info"
$b[20] = "closeinfo"
xFunction[21] = "Close Sharing"
$b[21] = "closesharing"
xFunction[22] = "Print Window"
$b[22] = "printwindow"
xFunction[23] = "Page Setup"
$b[23] = "pagesetup"
xFunction[24] = "Zoom Out"
$b[24] = "zoomout"
xFunction[25] = "Zoom In"
$b[25] = "zoomin"
xFunction[26] = "Move Window"
xFunction[27] = "Size Window"
xFunction[28] = "View"
xFunction = 28
menu new,21,0,xFunction
menuscript 20,List
menuscript 21,Function
a = 'Small Icon Name Date Size Kind Comment Label Version'
lval a,$Kind
*
script List
if #arg(2) = 1
    $list = 0
else if #arg(2) = 2
    dir
    test (#ret) exit
    listdir ll
    list ll,'Select Files'
    i = 0
    do
        listnext ll,i
        test (i = 0) exit
        inc $list
        alias $list[$list] = ,ll[i]
        if #ret
            dec $list
        else
            $type[$list] = 1
        end
    end
else if #arg(2) = 3
    dir
    test (#ret) exit
    inc $list
    alias $list[$list] = ,
    if #ret
        dec $list
    else
        $type[$list] = 0
    end
else if #arg(2) = 4
    $dest = 0
    dir
    test (#ret) exit
    alias $list[0] = ,
    test (#ret = 0) $dest = 1
else if #arg(2) = 5
    $dest = 0
    path trsh,
    alias $list[0] = ,
    test (#ret = 0) $dest = 1
else if #arg(2) = 6
    $dest = 0
    path desk,
    alias $list[0] = ,
    test (#ret = 0) $dest = 1
end
*
script Function
if #arg(2) < 6
    front sign='MACS'
    finder ($b[#arg(2)])
else if $list = 0
    display 'No Items in List'
    exit
else if (#arg(2) = 15 || #arg(2) = 16) && $dest = 0
    display 'No Destination Folder'
    exit
else if #arg(2) < 17
    front sign='MACS'
    finder ($b[#arg(2)]),$list
else if #arg(2) < 26
    front sign='MACS'
    i = 0
    do while i < $list
        inc i
        test ($type[i] && #arg(2) != 20) cycle
        finder ($b[#arg(2)]),$list[i]
    end
else if #arg(2) = 26
    exec coordinates,"$top",'Window Top Coordinate',"$left",'Window Left Coordinate'
    test (#ret) exit
    front sign='MACS'
    i = 0
    do while i < $list
        inc i
        test ($type[i]) cycle
        finder movewindow,$list[i],top=$top,left=$left
    end
else if #arg(2) = 27
    exec coordinates,"$w",'Window Width',"$h",'Window Height'
    test (#ret) exit
    front sign='MACS'
    i = 0
    do while i < $list
        inc i
        test ($type[i]) cycle
        finder sizewindow,$list[i],height=$h,width=$w
    end
else if #arg(2) = 28
    list $Kind,"Select View Type",128
    test (#ret || $Kind[-1] = 0) exit
    j = 0
    listnext $Kind,j
    display $Kind[j]
    front sign='MACS'
    i = 0
    do while i < $list
        inc i
        test ($type[i]) cycle
        finder view,$list[i],($Kind[j])
    end
end

script coordinates
exec coordinate,#arg(1),#arg(2)
test (#ret) exit 1
exec coordinate,#arg(3),#arg(4)
exit #ret

script coordinate
do
    accept x,#arg(2)
    test (#ret) exit 1
    x = #expr(x)
    if #num(x) < 1
        display 'Non-integer value entered for '#arg(2)
    else
        {#arg(1)} = x
        exit
    end
end